COMPLEX ANALYSIS: Maple Worksheets, 2001
(c) John H. Mathews Russell W. Howell
mathews@fullerton.edu howell@westmont.edu

Complimentary software to accompany the textbook:

COMPLEX ANALYSIS: for Mathematics & Engineering, 4th Ed, 2001, ISBN: 0-7637-1425-9
Jones and Bartlett Publishers, Inc., 40 Tall Pine Drive, Sudbury, MA 01776
Tele. (800) 832-0034; FAX: (508) 443-8000, E-mail: mkt@jbpub.com, http://www.jbpub.com/


 CHAPTER 9 CONFORMAL MAPPING

Section 9.3 Mapping Involving Elementary Functions

In Section 5.1 we saw that the function w = f(z) = exp(z) is a one-to-one mapping of the fundamental period strip -pi*` < y ` <= pi in the z-plane onto the w-plane with the point w <> 0 deleted. Because `f '(z)` <> 0 , the mapping w = exp(z) a conformal mapping at each point z in the complex plane. The family of horizontal lines y = c for -pi*` < c ` <= pi , and the segments x = a and -pi*` < y ` <= pi form an orthogonal grid in the fundamental period strip. Their images under the mapping w = exp(z) are the rays 0 < rho and phi = c and the circles abs(w) = exp(a) , respectively. These images form an orthogonal curvilinear grid in the w-plane.

 

If -pi*` < c < d ` <= pi , then the rectangle `R = {x + iy: a<x<b, c<y<d}`

is mapped one-to-one and onto the region `G = {`*rho*exp(i*phi)*`: `*exp(a)*`<`*rho*`<`*ex...

 

The inverse mapping is the principal branch of the logarithm z = Log(w) .

 

Load Maple's "conformal mapping" procedure.
Make sure this is done only ONCE during a Maple session.

> with(plots):

 

Warning, the name changecoords has been redefined

Example 9.8, Page 372. The transformation w = (e^z-i)/(e^z+i) is a one-to-one conformal mapping
of the horizontal strip 0 < y < pi onto the disk abs(w) < 1 . Furthermore, the x -axis is mapped onto
the lower semicircle bounding the disk, and the line y = pi is mapped onto the upper semicircle.

> f:='f': g:='g': z:='z': Z:='Z':
f := z -> (exp(z)-I)/(exp(z)+I):
`f(z) ` = f(z);

`f(z) ` = (exp(z)-I)/(exp(z)+I)

To show f(z) = (e^z-i)/(e^z+i) is one-to-one conformal we need to find the inverse function.

> g:='g': i:='i': Z:='Z':
sol := solve((exp(Z)-i)/(exp(Z)+i) = w , Z):
`z ` = subs(i=I,sol);
g := w -> log((I+I*w)/(1-w)):
`f(z) ` = f(z);
`g(w) ` = g(w);
`g(f(z)) ` = simplify(g(f(z)));
`f(g(w)) ` = simplify(f(g(w)));

`z ` = ln(-I*(1+w)/(-1+w))

`f(z) ` = (exp(z)-I)/(exp(z)+I)

`g(w) ` = ln((I+I*w)/(1-w))

`g(f(z)) ` = ln(exp(z))

`f(g(w)) ` = w

 

The image is traced using a graph.

> f:='f': z:='z':
f := z -> (exp(z)-I)/(exp(z)+I):
`f(z) ` = f(z);
conformal(f(z), z=-6+I*0.01..6+I*3.14,
title=`w = (exp(z)-i)/(exp(z)+i)`,
labels=[`u`,`v`], tickmarks=[3,3],
grid=[17,17], numxy=[17,17],
scaling=constrained,
view=[-1..1,-1..1]);

`f(z) ` = (exp(z)-I)/(exp(z)+I)

[Maple Plot]

Thus, the image of the horizontal strip 0 < y < pi is the disk abs(w) < 1 .


Example 9.9, Page 373. The transformation w = Log((1+z)/(1-z)) is a one-to-one conformal mapping
of the unit disk abs(z) < 1 onto the horizontal strip abs(v) < pi/2 . Furthermore, the upper semicircle of
the disk is mapped onto the line v = pi/2 and the lower semicircle onto v = -pi/2 .

> f:='f': g:='g': z:='z': Z:='Z':
f := z -> log((1+z)/(1-z)):
`w = f(z) ` = f(z);

`w = f(z) ` = ln((1+z)/(1-z))

To show that f(z) = Log((1+z)/(1-z)) is a one-to-one conformal mapping, we need to find the inverse function.

> g:='g': W:='W': Z:='Z':
sol := simplify(solve(f(Z)=W, Z)):
g := w -> subs(W=w,sol):
`f(z) ` = f(z);
`g(w) ` = g(w);
`g(f(z)) ` = simplify(g(f(z)));
`f(g(w)) ` = simplify(f(g(w)));

`f(z) ` = ln((1+z)/(1-z))

`g(w) ` = (exp(w)-1)/(exp(w)+1)

`g(f(z)) ` = z

`f(g(w)) ` = ln(exp(w))

The image is traced using a graph.

> f:='f': z:='z':
f := z -> log((1+z)/(1-z)):
`f(z) ` = f(z);
conformal(f(Re(z)*exp(I*Im(z))), z=0.001..0.999+I*2*Pi,
title=`w = log((1+z)/(1-z))`,
labels=[`u`,`v`], tickmarks=[7,3],
grid=[17,17], numxy=[17,17],
scaling=constrained,
view=[-3..3,-1.6..1.6]);

`f(z) ` = ln((1+z)/(1-z))

[Maple Plot]

 

Thus, the image of the unit disk abs(z) < 1 is the horizontal strip abs(v) < pi/2 .


 Example 9.10, Page 373. The transformation w = (1+z)^2/((1-z)^2) is a one-to-one conformal mapping of the
portion of the unit disk abs(z) < 1 that lies in the upper half-plane 0 < Im(z) onto the upper half-plane 0 < Im(w) .
Furthermore, the upper semicircular portion of the boundary is mapped onto the negative u -axis, and
the segment -1 < x < 1 , y = 0 is mapped onto the positive u -axis.

> f:='f': z:='z':
f := z -> (1+z)^2/(1-z)^2:
`w = f(z) ` = f(z);

`w = f(z) ` = (1+z)^2/(1-z)^2

To show that f(z) = (1+z)^2/((1-z)^2) is one-to-one conformal mapping, we need to find the inverse
function. Since there is two branches, perhaps one of them is appropriate to this problem.

> g:='g': w:='w': W:='W': Z:='Z':
sol := solve(f(Z) = W, Z):
g := w -> subs(W=w,simplify(sol[1])):
`f(z) ` = f(z);
`g(w) ` = g(w);
gfz := g(f(z)):
`g(f(z)) ` = gfz;
gfz := subs(sqrt((1+z)^2/(1-z)^2)=-(1+z)/(1-z),gfz):
`g(f(z)) ` = gfz;
gfz := simplify(gfz):
`g(f(z)) ` = gfz;
fgw := simplify(f(g(w)),{assume=positive,sqrt}):
`f(g(w)) ` = fgw;

`f(z) ` = (1+z)^2/(1-z)^2

`g(w) ` = (1+w+2*sqrt(w))/(-1+w)

`g(f(z)) ` = (1+(1+z)^2/(1-z)^2+2*sqrt((1+z)^2/(1-z...

`g(f(z)) ` = (1+(1+z)^2/(1-z)^2-2*(1+z)/(1-z))/(-1+...

`g(f(z)) ` = z

`f(g(w)) ` = (w^2+2*w^(3/2)+w)/(1+w+2*sqrt(w))

 

The image is traced using a graph.

> f:='f': z:='z':
f := z -> (1+z)^2/(1-z)^2:
`f(z) ` = f(z);
conformal(f(Re(z)*exp(I*Im(z))), z=0.001+I*0.01..0.999+I*3.14,
title=`w = (1+z)^2/(1-z)^2`,
labels=[` u`,`v `], tickmarks=[5,3],
grid=[17,17], numxy=[17,17],
scaling=constrained,
view=[-4..4,0..4]);

`f(z) ` = (1+z)^2/(1-z)^2

[Maple Plot]

 

Thus the image of the portion of the unit disk abs(z) < 1 that lies in the
upper half-plane 0 < Im(z) is the upper half-plane 0 < Im(w) .


Example 9.11, Page 374. Consider the function w = sqrt(z^2-1) , which is the composition of the
functions Z = z^2-1 and w = sqrt(Z) where the branch of the square root is sqrt(Z) = sqrt(R)*(cos(Theta/2)+i*sin(Theta/2)) ,
where Theta = arg(Z) and 0 <= Theta < 2*pi . Then the transformation w = f(z) maps the upper half-plane 0 < Im(z)
one-to-one and onto the upper-half plane 0 < Im(w) slit along the segment u = 0 , 0 < v <= 1 .

> f:='f': z:='z':
f := z -> (z^2 - 1)^(1/2):
`w = f(z) ` = f(z);

`w = f(z) ` = sqrt(z^2-1)

To show f(z) = sqrt(z^2-1) is one-to-one conformal we need to find the inverse function.

> g:='g': w:='w': W:='W': Z:='Z':
sol := solve((Z^2 - 1)^(1/2) = W, Z):
g := w -> (w^2+1)^(1/2):
g := w -> subs(W=w,sol[1]):
`f(z) ` = f(z);
`g(w) ` = g(w);
`g(f(z)) ` = simplify(g(f(z)),assume=positive);
`f(g(w)) ` = simplify(f(g(w)),assume=positive);

`f(z) ` = sqrt(z^2-1)

`g(w) ` = sqrt(1+w^2)

`g(f(z)) ` = z

`f(g(w)) ` = w

 

However, in Maple's the branch cut for square root is along the negative x -axis. We need a version
of the functin f(z) with a branch cut along the positive x -axis: Thus, we will use f(z) = i*sqrt(1-z^2) .

> f:='f': z:='z':
f := z -> I*(1 - z^2)^(1/2):
`f(z) ` = f(z);

`f(z) ` = I*sqrt(1-z^2)

 

The image is traced using a graph.

> f:='f': g:='g': z:='z': Z:='Z':
f := z -> I*(1 - z^2)^(1/2):
`f(z) ` = f(z);
conformal(f(z), z=-2.5+I*0.01..2.5+I*1.35,
title=`w = i (1 - z^2)^(1/2)`,
labels=[` u`,`v `], tickmarks=[5,3],
grid=[16,16],numxy=[16,16],
scaling=constrained,
view=[-2.5..2.5,0..1.8]);

`f(z) ` = I*sqrt(1-z^2)

[Maple Plot]

 

End of Section 9.3.