COMPLEX ANALYSIS: Maple Worksheets, 2001
(c) John H. Mathews Russell W. Howell
mathews@fullerton.edu howell@westmont.edu

Complimentary software to accompany the textbook:

COMPLEX ANALYSIS: for Mathematics & Engineering, 4th Ed, 2001, ISBN: 0-7637-1425-9
Jones and Bartlett Publishers, Inc., 40 Tall Pine Drive, Sudbury, MA 01776
Tele. (800) 832-0034; FAX: (508) 443-8000, E-mail: mkt@jbpub.com, http://www.jbpub.com/

Check out the new Complex Analysis Projects page.


 CHAPTER 10 APPLICATIONS of HARMONIC FUNCTIONS

Section 10.7 Two-Dimensional Fluid Flow

Suppose that a fluid flows over the complex plane and that the velocity at the point z = x+i*y is given by the velocity vector

 

V(x,y) = p(x,y)+i*q(x,y) .


We also require that the velocity does not depend on time and that the components p(x,y) and q(x,y) have continuous partial derivatives.

 

The divergence of the vector field in equation 10-30 is given by

 

div*V(x,y) = Diff(p(x,y),x) + i Diff(q(x,y),y)

 

and is a measure of the extent to which the velocity field diverges near the point. We will consider only fluid flows for which the divergence is zero. This is more precisely characterized by requiring that the net flow through any simply closed contour be identically zero.

 

We will consider only fluid flows for which the curl is zero. Such fluid flows are called irrotational . This is more precisely characterized by requiring that the line integral of the tangential component of V(x,y) along any simply closed contour be identically zero.

 

The function f(z) = f(x,y) = p(x,y)-i*q(x,y) satisfies the Cauchy-Riemann equations and is an analytic function. Let F(z) denote the antiderivative of f(z) . Then

 

F(z) = F(x,y) = phi(x,y)+i*psi(x,y)

 

is called the complex potential of the flow and has the property

conjugate(`F '(z)`) = Diff(phi(x,y),x) - i Diff(psi(x,y),x) = p(x,y)+i*q(x,y) = V(x,y)

 

The function phi(x,y) is the velocity potential for the flow, and the curves phi(x,y) = K[1] are called equipotentials . The function psi(x,y) is the stream function , and the curves psi(x,y) = K[2] are called streamlines and describe the paths of the fluid particles.

 

Load Maple's "conformal mapping" and "contourplot" procedures.
Make sure this is done only ONCE during a Maple session.

> with(plots):

 

Warning, the name changecoords has been redefined

Example 10.23, Page 437. Consider the complex potential f(z) = A*z^2/2
where A is a positive real number. The velocity potential and stream function are:
 u(x,y) = A*(x^2-y^2)/2 and v(x,y) = A*x*y ., respectively.

> A:='A': f:='f': F:='F': u:='u': v:='v': x:='x': y:='y': z:='z':
F := z -> A/2 * z^2:
u := proc(x,y) A/2*(x^2-y^2) end:
v := proc(x,y) A*x*y end:
`The complex potential is F(z) ` = F(z);
`F(z) ` = evalc(subs(z=x+I*y,F(z)));
`The velocity potential is u(x,y) ` = u(x,y);
`The stream function is v(x,y) ` = v(x,y);

`The complex potential is F(z) ` = 1/2*A*z^2

`F(z) ` = 1/2*A*(x^2-y^2)+I*A*x*y

`The velocity potential is u(x,y) ` = 1/2*A*(x^2-...

`The stream function is v(x,y) ` = A*x*y

For illustration purposes, choose A = 1 .

> f:='f': z:='z':
f := z -> sqrt(z):
`f(z) ` = f(z);
conformal(f(z), z=-4..4+I*4,
title=`w = sqrt(z)`,
grid=[9,9], numxy=[17,17],
labels=[`x`,`y `],
scaling=constrained,
view=[0..2.3,0..2.3]);

`f(z) ` = sqrt(z)

[Maple Plot]

 


 Example 10.24, Page 437. Find the complex potential for an ideal fluid flowing
from left to right across the complex plane and around the unit circle abs(z) = 1 .

Consider the complex potential f(z) = A*(z + 1/z) where A is a positive real number.
The velocity potential and stream function are given by:
 u(x,y) = A*(x+x/(x^2+y^2)) and v(x,y) = A*(y-y/(x^2+y^2)) , respectively

> A:='A': f:='f': F:='F': u:='u': v:='v': x:='x': y:='y': z:='z':
F := z -> z + 1/z:
u := proc(x,y) x + x/(x^2+y^2) end:
v := proc(x,y) y - y/(x^2+y^2) end:
`The complex potential is F(z) ` = F(z);
`F(z) ` = evalc(subs(z=x+I*y,F(z)));
`The velocity potential is u(x,y) ` = u(x,y);
`The stream function is v(x,y) ` = v(x,y);

`The complex potential is F(z) ` = z+1/z

`F(z) ` = x+x/(x^2+y^2)+I*(y-y/(x^2+y^2))

`The velocity potential is u(x,y) ` = x+x/(x^2+y^...

`The stream function is v(x,y) ` = y-y/(x^2+y^...

> `v(x,y) ` = v(x,y);
contourplot(v(x,y), x=-2..2, y=0..2,
title=`v(x,y) = y - y/(x^2+y^2)`,
axes=boxed, grid=[40,20],
scaling=constrained);

`v(x,y) ` = y-y/(x^2+y^2)

[Maple Plot]

 

The inverse function of f(z) = z+1/z is g(z) = (z+sqrt(z^2-4))/2 .

> solset := solve(w=z+1/z,z):
`f(z) ` = F(z);
`g(z) ` = subs(w=z,solset[2]);

`f(z) ` = z+1/z

`g(z) ` = 1/2*z-1/2*sqrt(z^2-4)

 

We can use it to find the image of the flow.

> g1:='g1': g2:='g2': z:='z':
g1 := z -> (z + (z^2 - 4)^(1/2))/2:
g2 := z -> (z - (z^2 - 4)^(1/2))/2:
`g1(z) ` = g1(z);
graph1 := conformal(g1(z), z=0..3+I,
title=`w = (z + (z^2 - 4)^(1/2))/2`,
grid=[13,13], numxy=[25,25],
scaling=constrained,
view=[0..2.8,0..1.7]):
`g2(z) ` = g2(z);
graph2 := conformal(g2(z), z=-3+I*0.0001..-0.0001+I,
title=`w = (z - (z^2 - 4)^(1/2))/2`,
grid=[13,13], numxy=[25,25],
scaling=constrained,
view=[-2.8..0,0..1.7]):
display({graph1,graph2},
title=`Flow around |z| = 1.`,
tickmarks=[5,4],
scaling=constrained);

`g1(z) ` = 1/2*z+1/2*sqrt(z^2-4)

`g2(z) ` = 1/2*z-1/2*sqrt(z^2-4)

[Maple Plot]

 


 Example 10.25, Page 438. Consider the complex potential f(z) = A*sqrt(z^2+1) for an ideal
fluid flowing from left to right across the complex plane slit along the segment from -i to i .

> A:='A': f:='f': F:='F': u:='u': v:='v': x:='x': y:='y': z:='z':
F := z -> sqrt(z^2 + 1):
u := proc(x,y) Re(sqrt((x+I*y)^2 + 1)) end:
v := proc(x,y) Im(sqrt((x+I*y)^2 + 1)) end:
`The complex potential is F(z) ` = F(z);
`The velocity potential is u(x,y) ` = u(x,y);
`The stream function is v(x,y) ` = v(x,y);

`The complex potential is F(z) ` = sqrt(z^2+1)

`The velocity potential is u(x,y) ` = Re(sqrt((x+...

`The stream function is v(x,y) ` = Im(sqrt((x+...

 

> `v(x,y) ` = v(x,y);
contourplot(v(x,y), x=0..2, y=0..2,
title=`v(x,y) = Im(sqrt(z^2 + 1))`,
axes=boxed, grid=[25,25],
scaling=constrained);

`v(x,y) ` = Im(sqrt((x+I*y)^2+1))

[Maple Plot]

 

The inverse function of f(z) = sqrt(z^2+1) is g(z) = sqrt(z^2-1) .
We can use it to find the image of the flow.

> g1:='g1': g2:='g2': z:='z':
g1 := z -> (z^2 - 1)^(1/2):
g2 := z -> -(z^2 - 1)^(1/2):
`g1(z) ` = g1(z);
graph1 := conformal(g1(z), z=0.0001+I*0.0001..2+I,
grid=[11,11], numxy=[11,11],
scaling=constrained,
view=[-2..2,0..1.6]):
`g2(z) ` = g2(z);
graph2 := conformal(g2(z), z=-2+I*0.0001..-0.0001+I,
grid=[11,11], numxy=[11,11],
scaling=constrained,
view=[-2..2,0..1.6]):
display({graph1,graph2},
title=`w = (z^2 - 1)^(1/2)`,
tickmarks=[5,4],
scaling=constrained,
view=[-2..2,0..1.6]);

`g1(z) ` = sqrt(z^2-1)

`g2(z) ` = -sqrt(z^2-1)

[Maple Plot]

 

End of Section 10.7.